自作サインツール|RSIを使用したサインツールを作ってみよう!サンプルプログラムあり

皆さん、ミーでございます。

自作サインツールの作り方をサンプルプログラムを含めて配信しておりますが、今回は、RSIを使用したサインツールを皆様と一緒に作成してみようと思います。

サインツールの作成が初めてという方は、以下の記事を読んでから見ていただけると更に分かり易いです。

自作サインツールの作り方|環境準備とサンプル動作の確認を初心者にも分かり易く説明

2021年12月21日

RSIとは

まず、RSIとは何かについて説明します。(ご存じの方が多いと思いますが)

良く70~80%以上で買われすぎ、20~30%以下で売られすぎと言われますが、RSIとは、テクニカルチャートのひとつである、「Relative Strength Index」の頭文字をとったものです。

過去一定期間の上げ幅(前日比)の合計を、同じ期間の上げ幅の合計と下げ幅の合計を足した数字で割って、100を掛けたものであり、いくら値上がり、値下がりしたかはRSIでは判断できません

値動きを含めた判断ができないことはありますが、High/Lowエントリーの条件が明確なので、サインツールには組み込みやすいです。

 

RSIをサインツールに組み込む方法

RSIをサインツールに組み込む方法ですが、【iRSI】という関数を使用します。

【iRSI】の関数をMQLのソースプログラムから呼び出すことで、RSIの値を取得することができます。

iRSIの使い方

// iRSIの関数定義

double  iRSI(
   string       symbol,        // 通貨ペア
   int          timeframe,     // 時間軸
   int          period,        // 平均期間
   int          applied_price, // 適用価格
   int          shift          // シフト
   );

使い方は、以下のような感じです。

double iResultRSI = iRSI(NULL,0,14,PRICE_CLOSE,0);

iResultRSI には、通貨ペア、時間軸は現在表示されているものを対象に、平均期間は一般的な14、適用価格は「PRICE_CLOSE」の設定で、最新のローソク足の情報が設定されます。

iRSIのパラメーターである「period」は、赤枠の期間を指定。「applied_price」は赤枠の適用価格の種類を指定するものです。

 

RSIを使用したサインツール

早速、RSIを使用したサインツール(サンプル)のご紹介をします。

今回作成するのは、

1.単純なRSIの上限/下限でサイン表示するもの

2.最新+1つ前のローソク足でサイン表示するもの

の2つになります。

単純なRSIの上限/下限でサイン表示するもの

まずは、実際に動作するサンプルコードを記載しますので、XXX.mq4(XXXの名前は何でも良い)を作成し、コンパイルの実行をお願いします。

手順が分からない方は、
https://rpa-affiliate.com/2021/09/24/self-made-signtool-base/
の記事を参照してください。

#property indicator_chart_window
#property indicator_buffers 2

extern int RSI_Period= 14;
extern double RSI_High = 70.0;
extern double RSI_Low = 30.0;

double DrawReverseLowBuffer[];
double DrawReverseHighBuffer[];


int init()  {
   SetIndexStyle(0,DRAW_ARROW,STYLE_SOLID,1,clrMagenta);
   SetIndexStyle(1,DRAW_ARROW,STYLE_SOLID,1,clrRed);
   SetIndexArrow(0,234);
   SetIndexArrow(1,233);
   SetIndexBuffer(0,DrawReverseLowBuffer);
   SetIndexBuffer(1,DrawReverseHighBuffer);
   return(INIT_SUCCEEDED);
}

int start() {
   int counted_bars=IndicatorCounted(); 
   int limit = Bars - counted_bars;
   double iResultRSI;
  
   for (int i=limit-1;i>=0;i--){
      if(i == 0){
         DrawReverseLowBuffer[i] = EMPTY_VALUE;
         DrawReverseHighBuffer[i] = EMPTY_VALUE;
      }

      iResultRSI      = iRSI(NULL,0,RSI_Period,PRICE_CLOSE,i);
      if(iResultRSI >= RSI_High){
         DrawReverseLowBuffer[i]=High[i];
      }
      else if(iResultRSI <= RSI_Low){
         DrawReverseHighBuffer[i]=Low[i];
      }
   }

   return(0);
}

 

実行結果のイメージ

比較的サイン数は多いですが、騙しも多いことが分かりますよね!

 

サンプルコードの解説

それでは、サンプルコードで重要な部分の解説をしていきますね。

#property indicator_chart_window
#property indicator_buffers 2

extern int RSI_Period= 14;
extern double RSI_High = 70.0;
extern double RSI_Low = 30.0;

#property indicator_chart_window は、チャートウィンドウにサインを出すことを明示します。
#property indicator_buffers 2 は、使用するインジケーターの数で、HighのサインとLowのサインの2つであることを意味します。

”RSI_Period”は期間、RSI_HighはHighエントリーの値(70を超えたら)、RSI_LowはLowエントリーの値(30を下回ったら)を定義しています。

また、先頭に”extern”が記載されておりますが、これを付けると、以下の画像のように、ユーザーがMT4から値を変えられるようになります。ユーザーの利便性が向上しますので、適切に使い分けを行いたいですよね。逆に、ユーザーに変更して欲しくない値には、”extern”は使用しません。

int init()  {
   SetIndexStyle(0,DRAW_ARROW,STYLE_SOLID,1,clrMagenta);
   SetIndexStyle(1,DRAW_ARROW,STYLE_SOLID,1,clrRed);
   SetIndexArrow(0,234);
   SetIndexArrow(1,233);
   SetIndexBuffer(0,DrawReverseLowBuffer);
   SetIndexBuffer(1,DrawReverseHighBuffer);
   return(INIT_SUCCEEDED);
}

上記は、MT4起動時や呼ばれる特殊な関数(init)です。その関数の中に、サイン表示に必要なサインの太さ、アイコンの種類、そして、表示するサインの配列を設定します。これは、こういうものだと覚えておく程度で構いません。

   for (int i=limit-1;i>=0;i--){
      if(i == 0){
         DrawReverseLowBuffer[i] = EMPTY_VALUE;
         DrawReverseHighBuffer[i] = EMPTY_VALUE;
      }

      iResultRSI      = iRSI(NULL,0,RSI_Period,PRICE_CLOSE,i);
      if(iResultRSI >= RSI_High){
         DrawReverseLowBuffer[i]=High[i];
      }
      else if(iResultRSI <= RSI_Low){
         DrawReverseHighBuffer[i]=Low[i];
      }
   }

for文の中がロジックの処理となります。

ループ変数(i)の値が、limit-1から、0の間ループすることになり、初回は全てのローソク足、2回目以降は最新のローソク足が再計算されます。

次に、サイン表示配列に”EMPTY_VALUE”(空の値)を設定していますが、最新のローソク足はRSIの値が変動する可能性がありますので、一旦サイン表示なしに設定しています。

その後、RSIの値が70以上(RSI_Highで指定した値)、30以下(RSI_Lowで指定した値)になった場合に、HighまたはLowのサインを表示する処理となります。

最新+1つ前のローソク足でサイン表示するもの

次に、”最新+1つ前のローソク足でサイン表示するもの”について、サンプルコードを記載します。

なぜ、1つ前のローソク足を見るサインツールのサンプルをご紹介するか?ですが、より勝率が高いサインを出すためです。条件を複数指定することで、より勝率が期待できるエントリーポイントでサインを出すことが出来ます。

きっと、この記事を見られている皆様は、勝率が高いところでサインを出したい!って思われてますよね(笑)

#property indicator_chart_window
#property indicator_buffers 2

extern int RSI_Period= 5;
extern double RSI_High = 60.0;
extern double RSI_High_prev= 55.0;
extern double RSI_Low = 35.0;
extern double RSI_Low_prev= 40.0;

double DrawReverseLowBuffer[];
double DrawReverseHighBuffer[];


int init()  {
   SetIndexStyle(0,DRAW_ARROW,STYLE_SOLID,1,clrMagenta);
   SetIndexStyle(1,DRAW_ARROW,STYLE_SOLID,1,clrRed);
   SetIndexArrow(0,234);
   SetIndexArrow(1,233);
   SetIndexBuffer(0,DrawReverseLowBuffer);
   SetIndexBuffer(1,DrawReverseHighBuffer);
   return(INIT_SUCCEEDED);
}

int start() {
   int counted_bars=IndicatorCounted(); 
   int limit = Bars - counted_bars;
   double iResultRSI,iResultRSI_prev;
  
   for (int i=limit-1;i>=0;i--){
      if(i == 0){
         DrawReverseLowBuffer[i] = EMPTY_VALUE;
         DrawReverseHighBuffer[i] = EMPTY_VALUE;
      }
      iResultRSI      = iRSI(NULL,0,RSI_Period,PRICE_CLOSE,i);
      iResultRSI_prev = iRSI(NULL,0,RSI_Period,PRICE_CLOSE,i+1);
      if(iResultRSI_prev < RSI_High_prev && iResultRSI >= RSI_High){
         DrawReverseLowBuffer[i]=High[i];
      }
      else if(iResultRSI_prev > RSI_Low_prev && iResultRSI <= RSI_Low){
         DrawReverseHighBuffer[i]=Low[i];
      }
   }

   return(0);
}

 

実行結果のイメージ

条件が増えましたので、サイン数は減りましたが、勝率は高くなってますよね。こうして、サインツールと呼ばれるものは、条件を組み合わせることで、サインを出しています。言い換えれば、この条件が【企業秘密】ってことですよね。

サンプルコードの解説

それでは、サンプルコードで重要な部分の解説をしていきますね。

”単純なRSIの上限/下限でサイン表示するもの”のサインツールと重複する部分が多々ありますので、異なる部分のみ解説します。

extern double RSI_High = 60.0;
extern double RSI_High_prev= 55.0;
extern double RSI_Low = 35.0;
extern double RSI_Low_prev= 40.0;

条件の変数が2つ増えています。これは判断する条件として1つ前のローソク足のRSIが加わったためです。

      iResultRSI      = iRSI(NULL,0,RSI_Period,PRICE_CLOSE,i);
      iResultRSI_prev = iRSI(NULL,0,RSI_Period,PRICE_CLOSE,i+1);
      if(iResultRSI_prev < RSI_High_prev && iResultRSI >= RSI_High){
         DrawReverseLowBuffer[i]=High[i];
      }
      else if(iResultRSI_prev > RSI_Low_prev && iResultRSI <= RSI_Low){
         DrawReverseHighBuffer[i]=Low[i];
      }

そして、判定ロジックの部分が変わっております。

一つ前のローソク足のRSIが、RSI_High_prevの値より小さいことに加え、最新のローソク足のRSIが、RSI_Highの値より大きい場合に、Lowエントリーのサイン。

一つ前のローソク足のRSIが、RSI_Low_prevの値より大きいことに加え、最新のローソク足のRSIが、RSI_Lowの値より小さい場合に、Highエントリーのサイン。

を出すサインツールとなります。

サインツール作成の記事一覧はこちら

Sponsor Link








コメントを残す

メールアドレスが公開されることはありません。 * が付いている欄は必須項目です